Spis treści
Układy analogowe
PSpice. Pierwsze kroki.
I. Dzielnik napięcia - definicja topologii i przykładowe analizy.
Dzielnik napięcia I - topologia, definicje analiz
Dzielnik napięcia I * opis topologii układu R_R1 1 2 10k R_R2 2 0 10k R_Ro 2 0 100k ;to jest rezystor obciążenia * Definicja napięć wejściowych V_Vin 1 0 DC 5 SIN(0 5 1k) * definicja analiz .DC V_Vin 0 5 0.1 .TRAN 50n 3m * uruchamiamy moduł probe i kończymy .PROBE .END
Definicje kształtu przebiegu
V_Vin 1 0 DC 5 AC 1 SIN(0 5 1k 0.2m) V_Vin 1 0 DC 5 AC 1 SIN(0 5 15k 0 1000) V_Vin 1 0 DC 5 AC 1 EXP(1 2 200u 1u 1m 1u) V_Vin 1 0 DC 5 AC 1 PULSE( -2 4 0 0 1n 500u 1m) V_Vin 1 0 DC 5 AC 1 SFFM(0 5 10k 5 1k) V_Vin 1 0 DC 5 AC 1 PWL(0 -1 0.2m 0 0.4m 1 0.6m 3 1m 0 1.5m 2 2m 1)
Dzielnik napięcia II - definicja modelu
Dzielnik napięcia - II R_R1 1 2 10k R_R2 2 0 100k R_Ro 2 0 Rez 10k ;Rez to nazwa modelu V_Vin 1 0 DC 5 * definiujemy model i ustawiamy parametr .model Rez RES R=1 .DC RES Rez(R) 1K 100K 100 .TEMP 27 ;tu możesz zmienić temperaturę otoczenia .PROBE .END
III. Dzielnik napięcia - rodzina charakterystyk.
Dzielnik napięcia III - analiza parametryczna
Dzielnik III
R_R1 1 2 10k
R_R2 2 0 10k
R_Ro 2 0 {Rvar} ; tu ustalamy nazwę parametru
V_Vin 1 0 DC 5
* ustawiamy wartość parametr
.param Rvar=10k
* i określamy jak zmiania się parametr
.step param Rvar 1k 50k 2k
.DC V_Vin 0 5 0.1
.PROBE
.END
IV. Dzielnik napięcia - wpływ tolerancji rezystancji.
Dzielnik napięcia IV - analiza Monte Carlo
Dzielnik IV R_R1 1 2 R10 10k ; używamy nazwy modelu R10 dla rezystora R1 R_R2 2 0 R10 10k ; i R2 R_Ro 2 0 100k V_Vin 1 0 DC 5 * definiujemy model rezystora z 10% tolerancją .model R10 RES R=1 DEV=10% * definicja analiz .DC V_Vin 0 5 0.1 .MC 50 DC V(2) YMAX list output all .PROBE .END
V. Dzielnik napięcia - dopasowanie obciążenia.
Dzielnik napięcia V - dopasowanie obciążenia
Dzielnik napięcia - moc maksymalna na obciążeniu
R_R1 1 2 10k
R_R2 2 0 10k
R_Ro 2 0 {Rvar}
V_Vin 1 0 DC 5
* ustawiamy parametr
.param Rvar=47k
* określamy jak zmiania się parametr
.step param Rvar 1 100k 1k
* definicja analiz
.DC V_Vin 0 5 0.1
.PROBE
.END
VI. Dzielnik napięcia VI z potencjometrem.
Realizacja potencjometru
Dzielnik napięcia z potencjometrem
* Potencjometr - zakres regulacji 1u..(Rp+1u)
* stała 1u eliminuje zerową rezystancję - ograniczenie Spice'a
R1a 1 2 {((1-a)*Rp)+1u}
R1b 2 0 {(a*Rp)+1u}
* Parametry potencjometru (Rp - rezystancja, poz - pozycja 0..100)
.param a={poz/100}
.param Rp=10k
.param poz=50
* Zmiana położenia "suwaka"
.step param poz 0 100 10
* Napięcie wejściowe
Vwe 1 0 5V
* Wyznaczamy ch-kę Uwy=f(Uwe) dla różnych położeń "suwaka"
.DC Vwe 0 5 .1
.PROBE
.END
Wzmacniacz w układzie WE.
Parametry modelu tranzystora BC107B
*Model tranzystora BC107B .model BC107B NPN(Is=7.049f Xti=3 Eg=1.11 Vaf=59.59 Bf=381.7 Ise=59.74f + Ne=1.522 Ikf=3.289 Nk=.5 Xtb=1.5 Br=2.359 Isc=192.9p + Nc=1.954 Ikr=7.807 Rc=1.427 Cjc=5.38p Mjc=.329 Vjc=.6218 + Fc=.5 Cje=11.5p Mje=.2718 Vje=.5 Tr=10n Tf=438p Itf=5.716 + Xtf=14.51 Vtf=10)
Plik należy rozpakować do podkatalogu tools\pspice\library znajdującego sie w katalogu w którym został zainstalowany program.
Można też umieścić go w dowolnym miejscu i wskazać dyrektywą .LIB jego położenie
Dołączenie biblioteki
* Biblioteka europe.lib znajduje się w katalogu d:\biblioteki\ .LIB d:\biblioteki\europe.lib
Wzmacniacz selektywny.
Wzmacniacz selektywny
*Wzmacniacz selektywny
.LIB "ebipolar.lib"
V_Ucc 3 0 DC 12
V_Uwe 1 0 AC 1
Q_T1 4 2 5 BC107B
R_R1 3 2 82k
R_R2 2 0 12k
R_Re 5 0 8.2k
R_Ro 6 0 1MEG
C_C1 1 2 100n
C_C2 4 6 100n
C_Ce 5 0 1u
*Obwód rezonansowy
R_RC 3 4 {Rsel}
C_CC 3 4 1n
L_LC 3 4 830u
* zmieniamy rezystancję w obwodzie rezonansowym
.param Rsel=80k
.step param Rsel LIST 30k 60k 120k
.AC LIN 500 150k 200k
.PROBE
.END
Wzmacniacz operacyjny.
Do przeprowadzenia analizy pracy poniższych układów wymagany jest plik definiujący podobwód wzmacniacza operacyjnego uA741, a także biblioteka z elementami półprzewodnikowymi.
Podstawowe układy.
I. Układ odwracający.
Wzmacniacz operacyjny - układ odwracający
Wzmacniacz operacyjny odwracający
* dołączamy plik z modelem wzmacniacza operacyjnego
.INC wo_sub.cir
* napięcie zasilania
V_UZp 4 0 15V
V_UZn 0 5 15V
* parametry rezystorów
.param R1=1k
.param R2={R1*Rf/(R1+Rf)}
.param Rf=4.7k
* analiza dla różnych wartości Rf
.step param Rf LIST 10k 47k 100k
* napięcie wejściowe
V_Uwe 1 0 DC 100m AC 1 SIN(0 200m 1k)
* topologia
R_R1 1 2 {R1}
R_Rf 2 6 {Rf}
R_R2 3 0 {R2}
* Wywołanie podobwodu wzmacniacza operacyjnego uA741
*
* wejście nieodwracające
* | wejście odwracające
* | | zasilanie (+)
* | | | zasilanie (-)
* | | | | wyjście
* | | | | |
X_WO 3 2 4 5 6 ua741
* analiza w dziedzinie czasu
.TRAN 10n 3m
* analiza w dziedzinie częstotliwości
.AC DEC 50 1 1MEG
* analiza stałopradowa - charakterystyka przejściowa
.DC V_Uwe -200m 200m 10m
* transmitancja, rezystancja wejściowa i wyjściowa układu
* (patrz plik .out "SMALL-SIGNAL CHARACTERISTICS")
.TF V(6) V_Uwe
* zniekształcenia harmoniczne
* (patrz plik .out "FOURIER ANALYSIS")
.FOUR 1k V(6)
.options trtol=0.05
.probe
.end
Wzmacniacz operacyjny - układ nieodwracający
Wzmacniacz operacyjny nieodwracający
* dołączamy plik z modelem wzmacniacza operacyjnego
.INC wo_sub.cir
* napięcie zasilania
V_UZp 4 0 15V
V_UZn 0 5 15V
* parametry rezystorów
.param R1=1k
.param Rf=4.7k
* analiza dla różnych wartości Rf
.step param Rf LIST 10k 47k 100k
* napięcie wejściowe
V_Uwe 3 0 DC 100m AC 1 SIN(0 200m 1k)
* topologia
R_R1 0 2 {R1}
R_Rf 2 6 {Rf}
* Wywołanie podobwodu wzmacniacza operacyjnego uA741
*
* wejście nieodwracające
* | wejście odwracające
* | | zasilanie (+)
* | | | zasilanie (-)
* | | | | wyjście
* | | | | |
X_WO 3 2 4 5 6 ua741
* analiza w dziedzinie czasu
.TRAN 10n 3m
* analiza w dziedzinie częstotliwości
.AC DEC 50 1 1MEG
* analiza stałopradowa - charakterystyka przejściowa
.DC V_Uwe -200m 200m 10m
* transmitancja, rezystancja wejściowa i wyjściowa układu
* (patrz plik .out "SMALL-SIGNAL CHARACTERISTICS")
.TF V(6) V_Uwe
* zniekształcenia harmoniczne
* (patrz plik .out "FOURIER ANALYSIS")
.FOUR 1k V(6)
.options trtol=0.05
.probe
.end
III. Wtórnik napięciowy.
Wzmacniacz operacyjny - wtórnik napięciowy
Wzmacniacz operacyjny - wtórnik napięciowy
* dołączamy plik z modelem wzmacniacza operacyjnego
.INC wo_sub.cir
* napięcie zasilania
V_UZp 4 0 15V
V_UZn 0 5 15V
* parametry rezystorów
.param Rf=4.7k
* analiza dla różnych wartości Rf
.step param Rf LIST 10k 47k 100k
* napięcie wejściowe
V_Uwe 3 0 DC 100m AC 1 SIN(0 200m 1k)
* topologia
R_Rf 2 6 {Rf}
* Wywołanie podobwodu wzmacniacza operacyjnego uA741
*
* wejście nieodwracające
* | wejście odwracające
* | | zasilanie (+)
* | | | zasilanie (-)
* | | | | wyjście
* | | | | |
X_WO 3 2 4 5 6 ua741
* analiza w dziedzinie czasu
.TRAN 10n 3m
* analiza w dziedzinie czestotliwości
.AC DEC 50 1 1MEG
* analiza stałopradowa - charakterystyka przejściowa
.DC V_Uwe -200m 200m 10m
* transmitancja, rezystancja wejściowa i wyjściowa układu
* (patrz plik .out "SMALL-SIGNAL CHARACTERISTICS")
.TF V(6) V_Uwe
* zniekształcenia harmoniczne
* (patrz plik .out "FOURIER ANALYSIS")
.FOUR 1k V(6)
.options trtol=0.05
.probe
Wzmacniacz operacyjny - układ sumujący
Wzmacniacz operacyjny sumujący. .INC wo_sub.cir * napięcie zasilania V_UZp 4 0 15V V_UZn 0 5 15V * napięcie wejściowe V_Uwe1 1 0 DC 100m AC 1 SIN(0 25m 10k) V_Uwe2 3 0 DC 100m AC 1 PULSE(-100m 25m 50u 100u 150u 1m 2m) * topologia R_R1 1 2 47k R_R2 3 2 27k R_Rf 2 6 100k * wywołanie podobwodu wzmacniacza X_WO 0 2 4 5 6 ua741 * analiza w dziedzinie czasu *.TRAN 10n 3.5m .options trtol=0.05 .probe .end
Inne zastosowania.
I. Prostownik liniowy.
Wzmacniacz operacyjny - prostownik liniowy
Wzmacniacz operacyjny prostownik liniowy .LIB europe.lib .INC wo_sub.cir * napięcie zasilania V_UZp 4 0 15V V_UZn 0 5 15V * napięcie wejściowe V_Vwe 1 0 DC 100m AC 1 SIN(0 200m 1k) * topologia R_R1 1 2 10k R_R2 2 7 10k D_D1 7 6 D1N4148 R_R3 2 8 10k D_D2 6 8 D1N4148 * Wywołanie podobwodu wzmacniacza operacyjnego uA741 * * wejście nieodwracające * | wejście odwracające * | | zasilanie (+) * | | | zasilanie (-) * | | | | wyjście * | | | | | X_WO 0 2 4 5 6 ua741 * analiza w dziedzinie czasu *.TRAN 10n 2m * analiza w dziedzinie czestotliwości *.AC DEC 50 1 100MEG * analiza stałopradowa - charakterystyka przejściowa .DC V_Vwe -200m 200m 10m .options trtol=0.01 .probe .end
Wzmacniacz operacyjny - filtr dolnoprzepustowy
Wzmacniacz operacyjny filtr dolnoprzepustowy
* dołączamy plik z modelem wzmacniacza operacyjnego
.LIB eval.lib
* napięcie zasilania
V_UZp 5 0 15V
V_UZn 0 7 15V
* parametry rezystorów
* stosunek wartości pojemności kondensatorów
.param n=2
* wzmocnienie
.param k=1
* parametry - wartości elementów
.param C=5n
.param R=4.7k
.param R1=1k
* parametry - elementy obliczane
.param Rf={(k-0.9999)*R1}
.param C2={n*C}
* analiza dla różnych wartości R - zmiana Fg
.step param R LIST 10k 22k 33k
* analiza dla różnych wartości n - zmiana Q
*.step param n LIST 1 2 5
* analiza dla różnych wartości k - zmiana Q - Ku
*.step param k LIST 1 10 20
* napięcie wejściowe
V_Uwe 1 0 DC 100m AC 1 PULSE( -1 1 0 0 1n 1m 2m)
*V_Uwe 1 0 DC 100m AC 1 SIN(0 200m 1k)
* topologia
R_R1 3 0 {R1}
R_R2 1 4 {R}
R_R3 4 2 {R}
R_Rf 3 6 {Rf}
C_C1 2 0 {C}
C_C2 4 6 {C2}
* Wywołanie podobwodu wzmacniacza operacyjnego uA741
*
* wejście nieodwracające
* | wejście odwracające
* | | zasilanie (+)
* | | | zasilanie (-)
* | | | | wyjście
* | | | | |
X_WO 2 3 5 7 6 ua741
* analiza w dziedzinie czasu
.TRAN 10n 3m
* analiza w dziedzinie częstotliwości
.AC DEC 50 1 70k
.options trtol=0.05
.probe
.end
PSpise - dodatki.
Model tranzystora BF245C
* Tranzystor BF245C .model BF245C NJF(Beta=420u Rs=1 Rd=1 Betatce=-.5 Lambda=10m Vto=-5.25 + Vtotc=0 Cgd=5p M=.3333 Pb=1 Fc=.5 Cgs=5p Isr=1p Nr=2 Is=100f + N=1 Xti=3 Alpha=10u Vk=100 Kf=1E-18 Af=1)
Model tranzystora BC211
* Tranzystor BC211 .model BC211 NPN(Is=48f Xti=3 Eg=1.11 Vaf=45 Bf=203 Ise=50f Ne=1.5 Ikf=0 + Nk=.7 Xtb=1.5 Br=5.5 Isc=48f Nc=2 Ikr=0 Rc=.7 Cjc=25p Mjc=.417 + Vjc=.75 Fc=.5 Cje=85p Mje=.3431 Vje=.75 Tr=100n Tf=800p Itf=1.2 + Xtf=10 Vtf=5 RCO=5 GAMMA=6E-8 QCO=1E-11)
Model tranzystora BC313
* Tranzystor BC313 .model BC313 PNP(Is=44.3f Xti=3 Eg=1.11 Vaf=62 Bf=200 Ise=44.3f Ne=1.5 Ikf=2 + Nk=.7 Xtb=1.5 Br=10 Isc=0 Nc=2 Ikr=0 Rc=.5 Cjc=48p Mjc=.4218 + Vjc=.75 Fc=.5 Cje=95p Mje=.3937 Vje=.75 Tr=120n Tf=1.1n Itf=.1 + Xtf=.1 Vtf=5 RCO=3.5 GAMMA=2E-9 QCO=1E-11)
Model tranzystora BD135
* Tranzystor BD135 .model BD135 NPN(Is=40f Xti=3 Eg=1.11 Vaf=115.7 Bf=180.2 Ise=40f Ne=1.363 + Ikf=4.927 Nk=1.247 Xtb=1.5 Br=10 Isc=85f Nc=2 Ikr=0 Rc=0 + Cjc=19.23p Mjc=.3439 Vjc=.5635 Fc=.5 Cje=60.49p Mje=.3589 + Vje=.7585 Tr=116n Tf=550p Itf=1 Xtf=0 Vtf=10 + QCO=1E-10 GAMMA=1E-8 RCO=5)
Model tranzystora BD136
* Tranzystor BD136 .model BD136 PNP(Is=10f Xti=3 Eg=1.11 Vaf=95.7 Bf=178.7 Ise=134.1f Ne=1.553 + Ikf=2 Nk=.8366 Xtb=1.5 Br=5 Isc=85f Nc=2 Ikr=0 Rc=0 Cjc=60p + Mjc=.4 Vjc=.8 Fc=.8 Cje=115.6p Mje=.3766 Vje=.7703 Tr=116n + Tf=500p Itf=1 Xtf=0 Vtf=10 + QCO=1E-10 GAMMA=5E-9 RCO=5)
Modele diod Zenera
* Dioda Zenera Uz=3,3V .model DZ3V3 D (BV=3.3 DEV 5% IBv=5m NBV=15 DEV 30% CJO 100P DEV=10%) * Dioda Zenera Uz=5,1V .model DZ5V1 D (BV=5.1 DEV 5% IBv=5m NBV=11 DEV 30% CJO=100P DEV=10%) * Dioda Zenera Uz=5,6V .model DZ5V6_2 D (BV=5.6 DEV 5% IBv=5m NBV=10 DEV 30%) * Dioda Zenera Uz=6,2V .model DZ6V2 D (BV=6.2 DEV 5% Ibv=5m NBV=4 DEV 30%)
LTSpice IV.
I. Prostownik dwupołówkowy symetryczny.
Wpływ pojemności C na wartość napięcia tętnień
Pobierz plik .asc
Linki.
Jacek Izydorczyk, "PSPICE - komputerowa symulacja układów elektronicznych
OrCAD 10.5 wersja DEMO (275MB)
Oficjalna strona programu OrCAD
Wzmacniacz - prezentacja (.zip 35kB)
LTSpice - Linear Technology Spice. Inna wersja programu Spice z edytorem graficznym.
